^ pop-out codeShare ^
  1. <!--- This is a simple code share example using the mach-ii.cfc --->
  2. <!---
  3. License:
  4. Copyright 2006 Mach-II Corporation
  5. Licensed under the Apache License, Version 2.0 (the "License");
  6. you may not use this file except in compliance with the License.
  7. You may obtain a copy of the License at
  8. Unless required by applicable law or agreed to in writing, software
  9. distributed under the License is distributed on an "AS IS" BASIS,
  10. WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11. See the License for the specific language governing permissions and
  12. limitations under the License.
  13. Copyright: Mach-II Corporation
  14. Author: Peter J. Farrell (pjf@maestropublishing.com)
  15. $Id: mach-ii.cfc 4824 2006-11-15 07:40:00Z pfarrell $
  16. Created version: 1.1.1
  17. Updated version: 1.1.1
  18. Acknowledgement:
  19. Thank you to eCivis, Inc. for being the driving force behind
  20. the development of this component.
  21. Notes:
  22. - Compatible only with ColdFusion MX 7.0 and above.
  23. - Call loadFramework in your onApplicationStart() event.
  24. - Call handleRequest in your onRequestStart() or onRequest() events.
  25. N.B
  26. Do not implement the handleRequest() in onRequest() application event if you to
  27. utilitze any CFCs that implement AJAX requests, web services, Flash
  28. Remoting or event gateway requests.
  29. ColdFusion MX will not execute these types of requests if you implement
  30. the handleRequest() method in the onRequest() application event.
  31. --->
  32. <cfcomponent
  33. displayname="mach-ii"
  34. output="false"
  35. hint="Base component for Application.cfc integration">
  37. <!---
  38. PROPERTIES - DEFAULTS
  39. --->
  40. <!--- Set the path to the application's mach-ii.xml file. Default to ./config/mach-ii.xml. --->
  41. <cfparam name="MACHII_CONFIG_PATH" type="string" default="#ExpandPath('./config/mach-ii.xml')#" />
  42. <!--- Set the configuration mode (when to reload): -1=never, 0=dynamic, 1=always --->
  43. <cfparam name="MACHII_CONFIG_MODE" type="numeric" default="0" />
  44. <!--- Set the app key for sub-applications within a single cf-application. Default to the folder name. --->
  45. <cfparam name="MACHII_APP_KEY" type="string" default="#GetFileFromPath(ExpandPath('.'))#" />
  46. <!--- Whether or not to validate the configuration XML before parsing. Default to false. --->
  47. <cfparam name="MACHII_VALIDATE_XML" type="boolean" default="false" />
  48. <!--- Set the path to the Mach-II's DTD file. Default to /MachII/mach-ii_1_1.dtd. --->
  49. <cfparam name="MACHII_DTD_PATH" type="string" default="#ExpandPath('/MachII/mach-ii_1_1_1.dtd')#" />
  50. <!--- Set the version number of Mach-II --->
  51. <cfset MACHII_VERSION = "1.1.1.8" />
  52. <!---
  53. PUBLIC FUNCTIONS
  54. --->
  55. <cffunction name="loadFramework" access="public" returntype="void" output="false"
  56. hint="Loads the framework. Only call in onApplicationStart() event.">
  57. <!--- Create the AppLoader. No locking requires if called during the onApplicationStart() event. --->
  58. <cfset application[MACHII_APP_KEY] = StructNew() />
  59. <cfset application[MACHII_APP_KEY].appLoader = CreateObject('component', 'MachII.framework.AppLoader').init(MACHII_CONFIG_PATH, MACHII_DTD_PATH, MACHII_VALIDATE_XML, MACHII_VERSION) />
  60. <cfset request.MachIIReload = FALSE />
  61. </cffunction>
  62. <cffunction name="handleRequest" access="public" returntype="void" output="true"
  63. hint="Handles a Mach-II request. Recommend to call in onRequestStart() event.">
  64. <!--- Default is request.MachIIConfigMode if it is defined temporarily override the config mode --->
  65. <cfif StructKeyExists(request,"MachIIConfigMode")>
  66. <cfset MACHII_CONFIG_MODE = request.MachIIConfigMode />
  67. </cfif>
  69. <!--- Create the AppLoader if necessary. Double check required for proper multi-threading. --->
  70. <cfif NOT StructKeyExists(application, MACHII_APP_KEY)>
  71. <cflock name="application_#MACHII_APP_KEY#_reload" type="exclusive" timeout="120">
  72. <cfif NOT StructKeyExists(application, MACHII_APP_KEY)>
  73. <cfset loadFramework() />
  74. </cfif>
  75. </cflock>
  76. </cfif>
  77. <!--- Reload the configuration if necessary --->
  78. <cfif MACHII_CONFIG_MODE EQ 1 AND NOT StructKeyExists(request, "MachIIReload")>
  79. <cflock name="application_#MACHII_APP_KEY#_reload" type="exclusive" timeout="120">
  80. <cfset application[MACHII_APP_KEY].appLoader.reloadConfig(MACHII_VALIDATE_XML, MACHII_VERSION) />
  81. </cflock>
  82. <cfelseif MACHII_CONFIG_MODE EQ 0 AND application[MACHII_APP_KEY].appLoader.shouldReloadConfig()>
  83. <cflock name="application_#MACHII_APP_KEY#_reload" type="exclusive" timeout="120">
  84. <cfset application[MACHII_APP_KEY].appLoader.reloadConfig(MACHII_VALIDATE_XML, MACHII_VERSION) />
  85. </cflock>
  86. <cfelseif MACHII_CONFIG_MODE EQ -1>
  87. <!--- Do not reload config. --->
  88. </cfif>
  89. <!--- Handle the request --->
  90. <cfset application[MACHII_APP_KEY].appLoader.getAppManager().getRequestHandler().handleRequest() />
  91. </cffunction>
  92. <!---
  93. ACCESSORS - MACHII INTEGRATION
  94. --->
  95. <cffunction name="setProperty" access="public" returntype="void" output="false"
  96. hint="Sets the property value by name. Not available until loadFramework() has been called.">
  97. <cfargument name="propertyName" type="string" required="true" />
  98. <cfargument name="propertyValue" type="any" required="true" />
  99. <cfset getAppManager().getPropertyManager().setProperty(arguments.propertyName, arguments.propertyValue) /> />
  100. </cffunction>
  101. <cffunction name="getProperty" access="public" returntype="any" output="false"
  102. hint="Returns the property value by name. If the property is not defined, and a default value is passed, it will be returned. If the property and a default value are both not defined then an exception is thrown. Not available until loadFramework() has been called.">
  103. <cfargument name="propertyName" type="string" required="true" />
  104. <cfargument name="defaultValue" type="any" required="false" default="" />
  105. <cfreturn getAppManager().getPropertyManager().getProperty(arguments.propertyName, arguments.defaultValue) />
  106. </cffunction>
  107. <cffunction name="isPropertyDefined" access="public" returntype="boolean" output="false"
  108. hint="Checks if property name is defined in the properties. Not available until loadFramework() has been called.">
  109. <cfargument name="propertyName" type="string" required="true"/>
  110. <cfreturn getAppManager().getPropertyManager().isPropertyDefined(arguments.propertyName) />
  111. </cffunction>
  113. <cffunction name="getAppManager" access="public" returntype="MachII.framework.AppManager" output="false"
  114. hint="Get the Mach-II AppManager. Not available until loadFramework has been called.">
  115. <cfreturn application[MACHII_APP_KEY].appLoader.getAppManager() />
  116. </cffunction>
  118. <cffunction name="shouldReloadConfig" access="public" returntype="boolean" output="false"
  119. hint="Returns if the config should be dynamically reloaded.">
  120. <cfreturn application[MACHII_APP_KEY].appLoader.shouldReloadConfig() />
  121. </cffunction>
  122. </cfcomponent>